Research in programming Wikidata/Protected area

This article is devoted to the study of the Wikidata object "nature protection zone".
Using SPARQL queries, the following tasks were solved:

List of all instances of the "protected area" object is displayed.
List of all "protected area" objects located in the Russia is displayed.
A column chart is constructed showing the dynamics of the change in the number of inceptions of protected areas in Russia and in the world for decades.
A bubble diagram is constructed showing the ratio of the number of protected areas in different countries.

Also, the completeness analysis of the Wikis was performed, information was added to some of the objects.

List of protected areas

Objects: protected area (Q473972)
Property: instance of (P31), subclass of (P279).

Let's create a list of all protected areas.

#added 2017-02
#List of `instances of` "protected area" 
SELECT ?area ?areaLabel
WHERE
{
    ?area (wdt:P31/wdt:P279*) wd:Q473972.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
}

SPARQL-query, 32639 results.

The most complete and elaborated protected areas on the Wikidata are: Jiuzhaigou, Krakatau, Kingman Reef. >

Almost empty and uninformative protected areas are: Shulgan-Tash (reserve), Orenburg Nature Reserve, Ajloun Forest Reserve. >

Russian protected areas

Let's create a list of protected areas located on the territory of Russia.

Objects: Russia (Q159), protected area (Q473972)
Properties: country (P17), instance of (P31), subclass of (P279).

 #added 2017-03
SELECT ?area ?areaLabel        #List of `instances` ... 
WHERE
{
  ?area (wdt:P31/wdt:P279*) wd:Q473972.    # ... of "protected area" ...  
  ?area wdt:P17 wd:Q159.                   # ... belonging to "Russia"
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en"}
}

SPARQL-query, 819 results.

Protected areas by the date of foundation

Let's create a histogram showing the number of inceptions of protected areas for decades.

Objects: protected area (Q473972), Russia (Q159), Soviet Union (Q15180), Russian Empire (Q34266)
Properties: inception (P571), instance of (P31), country (P17)

Around the world

 # added 2017-03
#defaultView: BarChart
SELECT (str(?decade) AS? decade) (COUNT(?inception) AS ?quantity) # number of "inceptions" ...
WHERE {
  ?item wdt: P31 wd: Q473972. # ... of "protected areas" ...
  
  ?item wdt: P571? Inception.
  BIND (YEAR(?inception) as ?year)
  BIND (FLOOR(?year / 10) * 10 as ?decade) # ... per each 10 years
}
GROUP BY ?decade # Group by decade
ORDER BY ?decade # Order by decade

SPARQL-query, 12 results.

In Russia

#added 2017-03
#defaultView:BarChart 
SELECT (str(?decade) AS ?decade) (COUNT(?inception) AS ?quantity) (SAMPLE(?countryLabel) AS ?countryLabel) # ... of the number of "inceptions" ...
WHERE {
  ?item wdt:P31 wd:Q473972. # ... of "protected areas" ...
  ?item wdt:P571 ?inception.
  ?item wdt:P17 ?country.
  
  { ?item wdt:P17 wd:Q159 } UNION   # ... belonging to "Russia", ...
  { ?item wdt:P17 wd:Q15180 } UNION # ... "Soviet Union" ...
  { ?item wdt:P17 wd:Q34266 }       # ... and "Russian Empire" ...
  
  BIND(YEAR(?inception) as ?year ) 
  BIND( FLOOR(?year/10)*10 as ?decade ) # ... per each 10 years
  
  ?country rdfs:label ?countryLabel.
  FILTER((LANG(?countryLabel)) = "en")
} 
GROUP BY ?decade # Group by decade
ORDER BY ?decade # Order by decade

SPARQL-query, 7 results.

Comparison and analysis of the growth dynamics of protected areas in Russia and around the world

Similarities:

There is a reduction of the number of zones in the 1940s (three zones) and 1960s (12 zones) in the world and total absence in Russia. Probably, the reason for this was the Second World War and the extensive economic development in the 1960s (the allocation of large areas for monoculture).
There is an active growth of the number of protected areas since the early 1970s. Maximum indicators in the 1990s: 12 new zones in Russia, 185 in the world.
There is a sharp drop of the number of new nature protection zones after 2010 (16 new zones in the world, one - in Russia). Most likely the situation is due to the deteriorating environmental situation and is trivial due to the fact that mankind has already taken control of most of the natural areas that require it.

Differences:

There is a sharp increase of the number of new zones in the 1950s in the world (46 new zones), a decrease in Russia (one new zone - Shulgan-Tash National Park).

Protected areas in different countries

Let's show the ratio of the number of nature protected areas in different countries of the world using a bubble diagram.

Objects: protected area (Q473972).
Properties: country (P17), instance of (P31), subclass of (P279).

#defaultView:BubbleChart
SELECT ?area ?country (count(*) as ?count) # number of ...
WHERE
{
	?pid (wdt:P31/wdt:P279*) wd:Q473972 . # ... "protected areas" ...
	?pid wdt:P17  ?area . # ... in different countries of the world
	OPTIONAL {
		?area rdfs:label ?country 
		filter (lang(?country ) = "en")
	}
}
GROUP BY ?area ?country
ORDER BY DESC(?count) ASC(?country)

SPARQL-query, 184 results.

As a result of the script we got 184 countries with protected areas. The leading positions are occupied by the United States of America (5,075 zones), Germany (4,921 zones) and the Czech Republic (4,111 zones).

Completeness of Wikidata

Unfilled property "inception"

According to the article "Protected area" of Russian Wikipedia there are 147 thousand protected areas in the world. As an authoritative source there is article by V. V. Dyozhkin "Specially Protected Natural Territories of the World", but the link is non-working. After searching the Internet it was found the article with outdated information about 102 thousand protected areas, as of 2003.

According to the article "Protected area" of English Wikipedia there are 161 thousand protected areas in the world. As an authoritative source there is the Internet service Protected Planet, managed by the World Conservation Monitoring Center, with the support of IUCN. This site is the most complete database of protected areas, but at the moment it allows to obtain global statistics only for a single country. For example, according to the service, 11,251 protected areas are located on the territory of Russia.

Also, according to the website of the international forum IUCN World Parks Congress, there are about two hundred thousand protected areas in the world. ^[1]

With the help of the request "List of protected areas" we get only 32639 results around the world, because there are no Wikipedia records on most nature conservation zones - they have a low notability. Basically, these are protected areas of regional importance. For example, according to the article "Protected areas of Russia" of Russian Wikipedia only 299 protected areas have federal significance.

If you refer to queries "Protected areas by the date of foundation", then the results are even smaller. For example, in Russia, the Wikidata contains only 25 areas. This is due to the fact that most objects do not have the property "foundation date".

Let's show these objects using the script:

  #added 2017-03
SELECT ?area ?areaLabel ?inception        #List of `instances` ... 
WHERE
{
  ?area wdt:P31 wd:Q473972.    # ... of "protected area" ...  
  ?area wdt:P17 wd:Q159.       # ... belonging to "Russia"
  
  FILTER NOT EXISTS { ?area wdt:P571 [] }  #... with unfilled property "inception"
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en"}
}

SPARQL-query, 262 results.

As a result of the script, we got list of 262 instances of the "protected area" object belonging to Russia, with the unfilled "foundation date" property (until 20.03.2017).

Filling in the "inception" property of 100 objects

As of March 19, 2017, the Wikidata contained 25 russian protected areas with completed "date of foundation" property.

Today (May 21, 2017), the Wikidata contains 131 russian protected areas with completed "date of foundation" property.

Future work

List all protected areas with the filled "area" property. Sort in descending order.
List 10 protected areas which are located closest to the north pole (and also their coordinates).
Group protected areas by country and by "IUCN protected zone category" property. Based on the obtained data, construct a column diagram reflecting the ratio of the number of protected areas of different categories in each country.