File:Subgroup of Oh; S4 blue red; example solid.png
From Wikiversity
Jump to navigation
Jump to search
Size of this preview: 600 × 600 pixels. Other resolutions: 240 × 240 pixels | 480 × 480 pixels | 768 × 768 pixels | 1,024 × 1,024 pixels | 2,048 × 2,048 pixels | 4,000 × 4,000 pixels.
Original file (4,000 × 4,000 pixels, file size: 1.71 MB, MIME type: image/png)
This is a file from the Wikimedia Commons. The description on its description page there is shown below.
Commons is a freely licensed media file repository. You can help. |
Summary
DescriptionSubgroup of Oh; S4 blue red; example solid.png | Cuboctahedron without mirror symmetry, representing subgroup O or [4,3]+ (chiral octahedral symmetry) of the symmetry group of the cube | ||
Source | Own work | ||
Author |
|
Licensing
I, the copyright holder of this work, hereby publish it under the following licenses:
Permission is granted to copy, distribute and/or modify this document under the terms of the GNU Free Documentation License, Version 1.2 or any later version published by the Free Software Foundation; with no Invariant Sections, no Front-Cover Texts, and no Back-Cover Texts. A copy of the license is included in the section entitled GNU Free Documentation License.http://www.gnu.org/copyleft/fdl.htmlGFDLGNU Free Documentation Licensetruetrue |
This file is licensed under the Creative Commons Attribution 4.0 International license.
- You are free:
- to share – to copy, distribute and transmit the work
- to remix – to adapt the work
- Under the following conditions:
- attribution – You must give appropriate credit, provide a link to the license, and indicate if changes were made. You may do so in any reasonable manner, but not in any way that suggests the licensor endorses you or your use.
You may select the license of your choice.
POV-Ray source
#version 3.6;
global_settings { assumed_gamma 1.0 }
#default{ finish{ ambient 0.1 diffuse 0.9 conserve_energy}}
#include "colors.inc"
#declare CubeColor = rgb<0.25, 0.25, 0.25>;
#declare CuboctaDark = rgb<0.25, 0.05, 0.05>;
#declare CuboctaLight = rgb<0.7, 0.4, 0.2>;
#declare R = 0.085;
#declare Rs = 0.45*R;
#declare Rb = 2*R;
///////////////////////////// camera and light
#declare Camera_Position = <12, 12, -50>;
camera{
location Camera_Position
right x*image_width/image_height
angle 6.7
look_at <-0.09, -0.14, 0.1>
}
light_source{ <-400, 500, -300> color White*0.9 shadowless}
light_source{ Camera_Position color rgb<0.9,0.9,1>*0.1 shadowless}
sky_sphere{ pigment{ White } }
///////////////////////////// cube edges
#declare S = 4.5;
#declare CubeCoordinates = array[8]{
<-2.25, -2.25, -2.25>,
< 2.25, -2.25, -2.25>,
<-2.25, -2.25, 2.25>,
< 2.25, -2.25, 2.25>,
<-2.25, 2.25, -2.25>,
< 2.25, 2.25, -2.25>,
<-2.25, 2.25, 2.25>,
< 2.25, 2.25, 2.25>
}
#declare CubeEdgesAbstractCoordinates = array[12][2]{
{0,1}, {2,3}, {4,5}, {6,7}, {0,2}, {1,3}, {4,6}, {5,7}, {0,4}, {1,5}, {2,6}, {3,7}
}
#declare Cube = union{
#for(i, 0, 7)
sphere{CubeCoordinates[i], 0.01}
#end
#for(i, 0, 11)
cylinder{
CubeCoordinates[CubeEdgesAbstractCoordinates[i][0]],
CubeCoordinates[CubeEdgesAbstractCoordinates[i][1]],
0.01
}
#end
pigment{color CubeColor}
}
///////////////////////////// cube solid
box{
CubeCoordinates[0]
CubeCoordinates[7]
pigment{color rgbt<0.9, 0.9, 0.9, 0.87> }
}
///////////////////////////// cuboctahedron
#declare Cuboctahedron = union{
#declare Dist = 0.25*S;
#declare PointA = CubeCoordinates[4] + 0.5*S*x;
#declare PointB = CubeCoordinates[1] + 0.5*S*y;
#declare PointC = CubeCoordinates[1] + 0.5*S*z;
#declare PointD = CubeCoordinates[2] + 0.5*S*x;
#declare PointE = CubeCoordinates[2] + 0.5*S*y;
#declare PointF = CubeCoordinates[4] + 0.5*S*z;
#declare PointB1 = PointB - Dist*x + Dist*y;
#declare PointB2 = PointB - Dist*y + Dist*z;
#declare PointD1 = PointD + Dist*x - Dist*z;
#declare PointD2 = PointD + Dist*y - Dist*x;
#declare PointF1 = PointF + Dist*x - Dist*z;
#declare PointF2 = PointF + Dist*z - Dist*y;
#declare Unit = union{
// dark
sphere{PointB1, R}
sphere{PointB2, R}
cylinder{PointB, PointB1, R}
cylinder{PointB, PointB2, R}
sphere{PointD1, R}
sphere{PointD2, R}
cylinder{PointD, PointD1, R}
cylinder{PointD, PointD2, R}
sphere{PointF1, R}
sphere{PointF2, R}
cylinder{PointF, PointF1, R}
cylinder{PointF, PointF2, R}
sphere{PointB, Rb}
sphere{PointD, Rb}
sphere{PointF, Rb}
// light
union{
sphere{PointA, Rs}
sphere{PointC, Rs}
sphere{PointE, Rs}
cylinder{PointA, PointB, Rs}
cylinder{PointB, PointC, Rs}
cylinder{PointC, PointD, Rs}
cylinder{PointD, PointE, Rs}
cylinder{PointE, PointF, Rs}
cylinder{PointF, PointA, Rs}
pigment{color CuboctaLight}
}
scale -x scale -y scale -z
}
#declare Unit = union{
object{Unit}
object{Unit rotate 180*z}
}
#declare Unit = union{
object{Unit}
object{Unit rotate 90*z}
}
object{Unit}
pigment{color CuboctaDark}
}
///////////////////////////// show
object{Cube}
object{Cuboctahedron}
Items portrayed in this file
depicts
File history
Click on a date/time to view the file as it appeared at that time.
Date/Time | Thumbnail | Dimensions | User | Comment | |
---|---|---|---|---|---|
current | 00:56, 4 May 2017 | 4,000 × 4,000 (1.71 MB) | Watchduck |
File usage
The following 2 pages use this file:
Metadata
This file contains additional information, probably added from the digital camera or scanner used to create or digitize it.
If the file has been modified from its original state, some details may not fully reflect the modified file.
PNG file comment |
|
---|---|
File change date and time | 00:24, 4 May 2017 |
Software used |
|